高抛低吸 同花顺分时指标

源码

均价:=MONEY/VOL;
e:=(NEW-均价)/均价;
//(1)上涨动量指标;
IF(FORMATTIME(1)>0)
{
DIFF :=EMA(NEW,5) - EMA(NEW,12);
DEA  :=EMA(DIFF,9);
上涨动量 :2*(DIFF-DEA)*100;
}
ELSE
{
DIFF:=0;
DEA:=0;
上涨动量:0;
}
//(2)大单指标与大单差值{大单指标};
DDJL:=((BIGBUYCOUNT1+BIGBUYCOUNT2+WAITBUYCOUNT1+WAITBUYCOUNT2)-(BIGSELLCOUNT1+BIGSELLCOUNT2+WAITSELLCOUNT1+WAITSELLCOUNT2))/SHGZG*100;
zdm:=(BIGBUYCOUNT1+BIGBUYCOUNT2)/SHGZG*100;
dm:=ddjl-REF(ddjl,1);
dz:=zdm-REF(zdm,1);
zdzq:=COUNT(dz=0,3)>=2;
//(3)成交量{成交量指标};
b:=MAX(0,SUBSAMEDAY(&VOL));
Vb:=SUM(b,FORMATTIME(1));
MA5b:=(SUM(b,6)-b)/5;
dv:=b/MA5b;
VL5:=SUM(b,5);
Vl51:=SUM(b,10)-SUM(b,5);
dl5:=Vl5/Vl51;
//(4)振幅和最低涨幅条件;
H1:=HHV(NEW,20);
L1:=LLV(NEW,20);
p1:=(H1-L1);
p2:=PRE;
zf:=p1/p2;
zd:=(NEW-L1)/PRE;
zg:=(NEW-H1)/PRE;
//5分钟震荡量
H0:=HHV(NEW,5);
L0:=LLV(NEW,5);
HL:=(H0-L0)/PRE;
MAhl:=MA(Hl,FORMATTIME(1));
dhl:=Hl/MAhl;
//(5)委托指标
委买:=BUYCOUNT;
委卖:=SELLCOUNT;
//(6)均线趋势指标
MA1:=MA(NEW,5);
MA2:=MA(NEW,30);
sv:=MA1-MA2;
sv1:=MA(NEW,2)-MA(NEW,5);
//卖出条件1
ss:=CROSS(dea,diff) AND 委卖>0  AND Hl>=0.01 AND dhl>1 AND e>0.02 AND zd>0.02;
sd:=COUNT(ss>0,FORMATTIME(1));
IF(sd<=1)
ss1:=ss;
ELSE
ss1:=0;
//买入条件1
zq:=BARSLAST(ss1>0);
jg:=REF(NEW,zq);
zff:=(NEW-REF(NEW,zq))/REF(NEW,zq);
bb:=CROSS(diff,dea) AND zff<-0.01 AND sd>0 AND dm>=0 AND dv>1 ;
ssb:=COUNT(bb>0,FORMATTIME(1));
IF(ssb<=1)
bb1:=bb;
ELSE
bb1:=0;
//卖出条件2 
H2:=HHV(NEW,MIN(FORMATTIME(1),10));
L2:=LLV(NEW,MIN(FORMATTIME(1),10));
zf1:=IF(FORMATTIME(1)>=10,(NEW-L2)/PRE,0);;
ss0:=CROSS(dea,diff) AND HHV(zf1,10)>0.03 AND HHV(zf1,10)<0.08AND 委卖>0 AND ss=0;
sd0:=COUNT(ss0>0,FORMATTIME(1));
IF(sd0<=1)
ss2:=ss0;
ELSE
ss2:=0;
//买入条件2
zq1:=BARSLAST(ss2>0);
jg:=REF(NEW,zq1);
zf2:=(NEW-REF(NEW,zq1))/REF(NEW,zq1);
bb0:=CROSS(diff,dea) AND sd0>0 AND ((zf2<-0.01 AND sv>0)OR (zf2<-0.02 AND sv1>0));
ssb1:=COUNT(bb0>0,FORMATTIME(1));
IF(ssb1<=1)
bb2:=bb0;
ELSE
bb2:=0;
FILLRGN(diff,dea,上涨动量>0,Color0000ff,上涨动量<0,Color00ff00);
//卖
DRAWTEXT(ss1>0,diff+0.8*ABS(diff),"高抛"),colorliblue;
DRAWTEXT(ss2>0 ,diff+0.8*ABS(diff),"出"),colorligreen;
VERLINE( ss1>0,1),colorwhite,LINETHICK2;
VERLINE(ss2>00,1),COLOR00FF00,LINETHICK2;
//买
DRAWTEXT(bb1>0,diff-0.1,"低吸"),colorred;
DRAWTEXT(bb2>0 ,diff-0.1,"入"),colorlired;
VERLINE( bb1>0,1),colorred,LINETHICK2;
VERLINE(bb2>0 ,1),colorlired,LINETHICK2;