通达信〖九星天轨〗九星共振做多信号若全部转弱看空信号源码
该指标是一套以多指标同步走强为核心的买卖信号系统。
功能机制：它将MACD、KD、RSI、CCI、BBI、MTM、DDZ、MA5及筹码等9个常用指标整合在一起，每个指标转强计为一颗“星”。副图中的指导线用于显示当前走强指标的数量：当9个指标同时转强时，触发“九星共振”做多信号；若全部转弱，则给出看空信号。
操作策略：重点观察共振强度。指导线升至7以上，说明多数指标方向一致，可视为偏强区域。若“九星共振”首日出现做多信号，较适合在低位或突破初期介入，止损参考信号K线低点。需要注意的是，9个指标同时共振属于极强条件，实际信号相对较少；实战中可先结合7星以上的偏强区域进行跟踪观察。一旦出现看空信号，持有股票应警惕回调风险。
DIFF:=EMA(CLOSE,8)-EMA(CLOSE,13);
DEA:=EMA(DIFF,5);
STICKLINE(DIFF>DEA,5,10,2,0),COLORRED;
STICKLINE(DIFF< DEA,5,10,2,0),COLORGREEN;
DRAWTEXT(ISLASTBAR=1,5,' . MACD'),COLORFFFFFF;
星1:=DIFF>DEA;
CHBKJ:=(CLOSE-LLV(LOW,8))/(HHV(HIGH,8)-LLV(LOW,8))*100;
K:=SMA(CHBKJ,3,1);
D:=SMA(K,3,1);
STICKLINE(K>D,12,17,2,0),COLORRED;
STICKLINE(K< D,12,17,2,0),COLORGREEN;
DRAWTEXT(ISLASTBAR=1,12,' . KD'),COLORFFFFFF;
星2:=K>D;
LC:=REF(CLOSE,1);
CBA1:=(SMA(MAX(CLOSE-LC,0),5,1))/(SMA(ABS(CLOSE-LC),5,1))*100;
CBA2:=(SMA(MAX(CLOSE-LC,0),13,1))/(SMA(ABS(CLOSE-LC),13,1))*100;
STICKLINE(CBA1>CBA2,19,24,2,0),COLORRED;
STICKLINE(CBA1< CBA2,19,24,2,0),COLORGREEN;
DRAWTEXT(ISLASTBAR=1,19,' . RSI'),COLORFFFFFF;
星3:=CBA1>CBA2;
SHIQUAN:=-(HHV(HIGH,13)-CLOSE)/(HHV(HIGH,13)-LLV(LOW,13))*100;
CHBKJ_1:=SMA(SHIQUAN,3,1);
CHBKJ_2:=SMA(CHBKJ_1,3,1);
STICKLINE(CHBKJ_1>CHBKJ_2,26,31,2,0),COLORRED;
STICKLINE(CHBKJ_1< CHBKJ_2,26,31,2,0),COLORGREEN;
DRAWTEXT(ISLASTBAR=1,26,' . CCI'),COLORFFFFFF;
星4:=CHBKJ_1>CHBKJ_2;
BBI:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
STICKLINE(CLOSE>BBI,33,38,2,0),COLOR00FFFF;
STICKLINE(CLOSE< BBI,33,38,2,0),COLORGREEN;
DRAWTEXT(ISLASTBAR=1,33,' . BBI'),COLORFFFFFF;
星5:=CLOSE>BBI;
MTM:=CLOSE-REF(CLOSE,1);
MMS:=100*EMA(EMA(MTM,5),3)/EMA(EMA(ABS(MTM),5),3);
MMM:=100*EMA(EMA(MTM,13),8)/EMA(EMA(ABS(MTM),13),8);
STICKLINE(MMS>MMM,40,45,2,0),COLORMAGENTA;
STICKLINE(MMS< MMM,40,45,2,0),COLORGREEN;
DRAWTEXT(ISLASTBAR=1,40,' . MTM'),COLORFFFFFF;
星6:=MMS>MMM;
MAV:=(C*2+H+L)/4;
SK:=EMA(MAV,13)-EMA(MAV,34);
SD:=EMA(SK,5);
DDZZ1:=(-2*(SK-SD))*3.8;
DDZZ2:=(2*(SK-SD))*3.8;
STICKLINE(DDZZ2>DDZZ1,47,52,2,0),COLORMAGENTA;
STICKLINE(DDZZ2< DDZZ1,47,52,2,0),COLORGREEN;
DRAWTEXT(ISLASTBAR=1,47,' . DDZ'),COLORFFFFFF;
星7:=DDZZ2>DDZZ1;
MA11:=MA(CLOSE,5);
MA22:=REF(MA(CLOSE,5),1);
STICKLINE(MA22>MA11,54,59,2,0),COLORGREEN;
STICKLINE(MA22<=MA11,54,59,2,0),COLORMAGENTA;
DRAWTEXT(ISLASTBAR=1,54,' . MA5'),COLORFFFFFF;
星8:=MA22<=MA11;
九星天轨3:=(2*CLOSE+HIGH+LOW)/4;
九星天轨4:=LLV(LOW,34);
九星天轨5:=HHV(HIGH,34);
ZHULI:=EMA((九星天轨3-九星天轨4)/(九星天轨5-九星天轨4)*100,13);
SANHU:=EMA(0.667*REF(ZHULI,1)+0.333*ZHULI,2);
STICKLINE(ZHULI< SANHU,61,66,2,0),COLORGREEN;
STICKLINE(ZHULI>SANHU,61,66,2,0),COLORMAGENTA;
DRAWTEXT(ISLASTBAR=1,61,' . 筹码'),COLORFFFFFF;
星9:=ZHULI>SANHU;
DDJ:=ZHULI>SANHU AND MA22<=MA11 AND DDZZ2>DDZZ1 AND MMS>MMM AND CHBKJ_1>CHBKJ_2 AND CBA1>CBA2 AND K>D AND DIFF>DEA AND C>BBI;
STICKLINE(CROSS(DDJ,0.5),68,73,4,0),COLOR0000FF;
共振首日:=DDJ AND REF(DDJ,1)=0;
DRAWICON(共振首日,69,9);
九星共振:DDJ,COLOR00FFFF,NODRAW;
做多天数:BARSLAST(NOT(DDJ)),COLOR0000FF,NODRAW;
KKJ:=ZHULI< SANHU AND MA22>MA11 AND DDZZ2< DDZZ1 AND MMS< MMM AND CHBKJ_1< CHBKJ_2 AND CBA1< CBA2 AND K< D AND DIFF< DEA AND C< BBI;
STICKLINE(CROSS(KKJ,0.5),68,73,4,0),COLORCYAN;
共振日:=KKJ AND REF(KKJ,1)=0;
DRAWICON(共振日,69,15);
看空天数:BARSLAST(NOT(KKJ)),COLOR00FF00,NODRAW;
指导线:=(星1+星2+星3+星4+星5+星6+星7+星8+星9),COLORFFFF00;
操作:IF(指导线>=7,47,0.9),LINETHICK1,COLORYELLOW;
X:0,DOTLINE,COLOR400040;
未来函数检测结果
DIFF赋值:收盘价的8日指数移动平均-收盘价的13日指数移动平均
DEA赋值:DIFF的5日指数移动平均
当满足条件DIFF>DEA时,在5和10位置之间画柱状线,宽度为2,0不为0则画空心柱.,画红色
当满足条件DIFF当满足条件是否最后一个周期=1时,在5位置书写文字,COLORFFFFFF
星1赋值:DIFF>DEA
CHBKJ赋值:(收盘价-8日内最低价的最低值)/(8日内最高价的最高值-8日内最低价的最低值)*100
K赋值:CHBKJ的3日[1日权重]移动平均
D赋值:K的3日[1日权重]移动平均
当满足条件K>D时,在12和17位置之间画柱状线,宽度为2,0不为0则画空心柱.,画红色
当满足条件K当满足条件是否最后一个周期=1时,在12位置书写文字,COLORFFFFFF
星2赋值:K>D
LC赋值:1日前的收盘价
CBA1赋值:(收盘价-LC和0的较大值的5日[1日权重]移动平均)/(收盘价-LC的绝对值的5日[1日权重]移动平均)*100
CBA2赋值:(收盘价-LC和0的较大值的13日[1日权重]移动平均)/(收盘价-LC的绝对值的13日[1日权重]移动平均)*100
当满足条件CBA1>CBA2时,在19和24位置之间画柱状线,宽度为2,0不为0则画空心柱.,画红色
当满足条件CBA1当满足条件是否最后一个周期=1时,在19位置书写文字,COLORFFFFFF
星3赋值:CBA1>CBA2
SHIQUAN赋值:-(13日内最高价的最高值-收盘价)/(13日内最高价的最高值-13日内最低价的最低值)*100
CHBKJ_1赋值:SHIQUAN的3日[1日权重]移动平均
CHBKJ_2赋值:CHBKJ_1的3日[1日权重]移动平均
当满足条件CHBKJ_1>CHBKJ_2时,在26和31位置之间画柱状线,宽度为2,0不为0则画空心柱.,画红色
当满足条件CHBKJ_1当满足条件是否最后一个周期=1时,在26位置书写文字,COLORFFFFFF
星4赋值:CHBKJ_1>CHBKJ_2
BBI赋值:(收盘价的3日简单移动平均+收盘价的6日简单移动平均+收盘价的12日简单移动平均+收盘价的24日简单移动平均)/4
当满足条件收盘价>BBI时,在33和38位置之间画柱状线,宽度为2,0不为0则画空心柱.,COLOR00FFFF
当满足条件收盘价当满足条件是否最后一个周期=1时,在33位置书写文字,COLORFFFFFF
星5赋值:收盘价>BBI
MTM赋值:收盘价-1日前的收盘价
MMS赋值:100*MTM的5日指数移动平均的3日指数移动平均/MTM的绝对值的5日指数移动平均的3日指数移动平均
MMM赋值:100*MTM的13日指数移动平均的8日指数移动平均/MTM的绝对值的13日指数移动平均的8日指数移动平均
当满足条件MMS>MMM时,在40和45位置之间画柱状线,宽度为2,0不为0则画空心柱.,画洋红色
当满足条件MMS当满足条件是否最后一个周期=1时,在40位置书写文字,COLORFFFFFF
星6赋值:MMS>MMM
MAV赋值:(收盘价*2+最高价+最低价)/4
SK赋值:MAV的13日指数移动平均-MAV的34日指数移动平均
SD赋值:SK的5日指数移动平均
DDZZ1赋值:(-2*(SK-SD))*3.8
DDZZ2赋值:(2*(SK-SD))*3.8
当满足条件DDZZ2>DDZZ1时,在47和52位置之间画柱状线,宽度为2,0不为0则画空心柱.,画洋红色
当满足条件DDZZ2当满足条件是否最后一个周期=1时,在47位置书写文字,COLORFFFFFF
星7赋值:DDZZ2>DDZZ1
MA11赋值:收盘价的5日简单移动平均
MA22赋值:1日前的收盘价的5日简单移动平均
当满足条件MA22>MA11时,在54和59位置之间画柱状线,宽度为2,0不为0则画空心柱.,画绿色
当满足条件MA22<=MA11时,在54和59位置之间画柱状线,宽度为2,0不为0则画空心柱.,画洋红色
当满足条件是否最后一个周期=1时,在54位置书写文字,COLORFFFFFF
星8赋值:MA22<=MA11
九星天轨3赋值:(2*收盘价+最高价+最低价)/4
九星天轨4赋值:34日内最低价的最低值
九星天轨5赋值:34日内最高价的最高值
ZHULI赋值:(九星天轨3-九星天轨4)/(九星天轨5-九星天轨4)*100的13日指数移动平均
SANHU赋值:0.667*1日前的ZHULI+0.333*ZHULI的2日指数移动平均
当满足条件ZHULI当满足条件ZHULI>SANHU时,在61和66位置之间画柱状线,宽度为2,0不为0则画空心柱.,画洋红色
当满足条件是否最后一个周期=1时,在61位置书写文字,COLORFFFFFF
星9赋值:ZHULI>SANHU
DDJ赋值:ZHULI>SANHU AND MA22<=MA11 AND DDZZ2>DDZZ1 AND MMS>MMM AND CHBKJ_1>CHBKJ_2 AND CBA1>CBA2 AND K>D AND DIFF>DEA AND 收盘价>BBI
当满足条件DDJ上穿0.5时,在68和73位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLOR0000FF
共振首日赋值:DDJ AND 1日前的DDJ=0
当满足条件共振首日时,在69位置画9号图标
输出九星共振:DDJ,COLOR00FFFF,NODRAW
输出做多天数:上次取反距今天数,COLOR0000FF,NODRAW
KKJ赋值:ZHULI< SANHU AND MA22>MA11 AND DDZZ2< DDZZ1 AND MMS< MMM AND CHBKJ_1< CHBKJ_2 AND CBA1< CBA2 AND K< D AND DIFF< DEA AND 收盘价< BBI
当满足条件KKJ上穿0.5时,在68和73位置之间画柱状线,宽度为4,0不为0则画空心柱.,画青色
共振日赋值:KKJ AND 1日前的KKJ=0
当满足条件共振日时,在69位置画15号图标
输出看空天数:上次取反距今天数,COLOR00FF00,NODRAW
指导线赋值:(星1+星2+星3+星4+星5+星6+星7+星8+星9),COLORFFFF00
输出操作:如果指导线>=7,返回47,否则返回0.9,线宽为1,画黄色
输出X:0,DOTLINE,COLOR400040
