月线 周线监视看盘主图 思路 源码

二根均线 3日线 10日线
一根蓝色线是250日最高价和250最低价的半价位画线
窗口位置显示月MACD月KDJ周MACD周KDJ金叉的位置（也就是金叉距今天的天数）其中年表示蓝色线的价格
保护价就是看盘时如果股价跌破这个价格就要小心了。
中心价位就是上一周周线实体的半分位价格
活跃股提示此股属于“活跃板块”
公式根据上周周K线的形态，会有一些买入 卖出提示文字，只能作为参考，自己盘中还得根据文字提示操盘。
文字提示主要参考上一周的周K线形态，不是本周的K线形态。
公式中有超级短线”买入“字样提示  这种提示只作为盘中持股的参考，另外再做选股没有必要  出票太多。前面我已经写了很多选股了。跟帖有要求改选股公式的同学不再答复。
指标只是一个参考，上面解释很清楚了，觉得有用就去下载。废话少说。
补充一点  主图中为何显示“未来函数”？这个不必介意 是画线函数DRAWTEXT引起的  如果改用STICKLINE函数画线就不会出现“未来函数数据”了。我觉得没必要改。自己拿捏吧

先建立一个引用
再次说明如何建引用
引用公式就如同你建主图 幅图公式步骤一样，只是引用公式不作为看盘使用，而是作为一个数据，建立后在今后的主图  幅图源码中要提取这个数据。
引用公式名字名字：  hg
cc:ref(c,1);
oo:ref(o,1);
hh:ref(h,1);
ll:ref(l,1);
退出该公式  再重新建立一个主图
月 周线监视看盘主图
周M金叉:IF("MACD.DIF#WEEK">="MACD.DEA#WEEK",BARSLAST(CROSS("MACD.DIF#WEEK","MACD.DEA#WEEK")),DRAWNULL) NODRAW;
月M金叉:IF("MACD.DIF#MONTH">="MACD.DEA#MONTH",BARSLAST(CROSS("MACD.DIF#MONTH","MACD.DEA#MONTH")),DRAWNULL) NODRAW;
周K金叉:IF("KDJ.K#WEEK">="KDJ.D#WEEK",BARSLAST(CROSS("KDJ.K#WEEK","KDJ.D#WEEK")),DRAWNULL) NODRAW;
月K金叉:IF("KDJ.K#MONTH">="KDJ.D#MONTH",BARSLAST(CROSS("KDJ.K#MONTH","KDJ.D#MONTH")),DRAWNULL) NODRAW;
TJJ:=(HHV(H,250)-LLV(L,250))/2+LLV(L,250);
年:CONST(TJJ)COLORBLUE;
保护价:(REF(C,2)+REF(C,1)+OPEN)/3,COLORRED;
M3:MA(C,3);
M10:MA(C,10);
TJ:=CROSS(MA(C,10)>=C,0.5) AND C<O;
NOTEXT1:=DRAWLINE(TJ,O,REF(TJ,1),REF(O,1),1);
NOTEXT2:=DRAWLINE(TJ,C,REF(TJ,1),REF(C,1),1);
TJ1:=CROSS(O<NOTEXT1 AND C>NOTEXT1,0.5);
DRAWTEXT(TJ1,L*0.95,'买入')COLORLIRED;
CC:="HG.CC#WEEK";
OO:="HG.OO#WEEK";
LL:="HG.LL#WEEK";
HH:="HG.HH#WEEK";
HUO:=IF(INBLOCK('活跃股'),1,0);
T:=CC=HH AND CC!=OO AND RANGE(OO/LL,0.90,1.01);
T1:=CC/OO>1.1 AND CC>OO AND LL<OO AND HH>CC;
T1A:=CC/OO<1.1 AND  CC>OO AND LL<OO AND HH>CC;
T2:=CC>OO AND HH>CC AND HH<CC*1.1 AND LL=OO;
T2A:=CC>OO AND HH>CC*1.1 AND LL=OO;
T3:=CC>OO AND HH<CC*1.1 AND HH>CC AND OO/LL>1.1;
T3A:=CC>OO AND HH/CC>1.1 AND LL<OO;
T4:=CC>OO AND HH=CC AND OO/LL>1.1;
T5A:=CC>OO AND HH=CC AND OO/LL<1.1;
Y1:=CC<OO AND HH=O AND LL=CC;
Y2:=CC<OO AND CC=LL AND HH>OO AND HH/OO<1.1;
Y3:=CC<OO AND HH=OO AND CC/LL<1.1 AND LL<CC;
Y4:=CC<OO AND HH>OO AND LL<CC;
Y5:=CC<OO AND LL=CC AND HH/OO>1.1;
Y6:=CC<OO AND LL=CC AND CC/LL>1.1;
Y7:=CC<OO AND LL<CC AND HH/OO>1.1 AND CC/LL<1.1;
Y8:=CC<OO AND CC/LL>1.1 AND HH>OO AND HH/OO<1.1;
AAA:=(MAX(CC,OO)-MIN(CC,OO))/2+MIN(CC,OO);
AA:=STRCAT(' [中心价位]：',VAR2STR(AAA,2));
A:='光头光脚大阳线，即将逆转，高位卖出';
A1:='光头光脚小阳线,回档不破中心价，继续收阳';
B:='大实体上下影，注意风险和上周相似可持有，实体大于上周，拉高出货';
B1:='小实体上下影，下跌以后关注中心价';
D:='短上光脚影阳，持有买入注意实体不要太大 比上周类似的小更好';
D1:='长上光脚影阳，谨慎变盘，影线越长越不安全';
E:='长下影阳线，上涨行情关注，下跌行情出局';
E1:='长上影阳线，开始整理 变盘';
F:='光头长下影，注意变盘向下，上升途中获利回吐';
G:='光头短下影，前面2阴可买入，如果前大阳见顶回落 出货，实体越小越好';
YA:='光头光脚阴，注意下周反弹';
YB:='光脚短上影，卖出';
YC:='短下影光头，前面有2阴可以建仓 否则 继续跌';
YD:='上下影阴线，上升途中变盘，下跌途中买入';
YE:='长上影光脚阴，持有或者关注';
YF:='长下影光脚阴，持股买入信号';
YG:='长上影阴，变盘信号';
YH:='长下影阴，拉高出货 如果有调整就可以买入';
DRAWTEXT_FIX(T AND CC/OO>1.1 AND ISLASTBAR,0.005,0.12,0,A),COLORYELLOW;
DRAWTEXT_FIX(CC/OO<1.1 AND T AND ISLASTBAR,0.005,0.18,0,A1),COLORYELLOW;
DRAWTEXT_FIX(HUO=1 AND ISLASTBAR,0.5,0.006,0,'活跃股'),COLORRED;
DRAWTEXT_FIX(T1 AND ISLASTBAR,0.005,0.12,0,B),COLORYELLOW;
DRAWTEXT_FIX(T1A AND ISLASTBAR,0.005,0.18,0,B1),COLORYELLOW;
DRAWTEXT_FIX(T2 AND ISLASTBAR,0.005,0.12,0,D),COLORYELLOW;
DRAWTEXT_FIX(T2A AND ISLASTBAR,0.005,0.18,0,D1),COLORYELLOW;
DRAWTEXT_FIX(T3 AND ISLASTBAR,0.005,0.12,0,E),COLORYELLOW;
DRAWTEXT_FIX(T3A AND ISLASTBAR,0.005,0.12,0,E1),COLORYELLOW;
DRAWTEXT_FIX(T5A AND ISLASTBAR,0.005,0.12,0,G),COLORYELLOW;
DRAWTEXT_FIX(Y1 AND ISLASTBAR,0.005,0.12,0,YA),COLORYELLOW;
DRAWTEXT_FIX(T4 AND ISLASTBAR,0.005,0.12,0,F),COLORYELLOW;
DRAWTEXT_FIX(Y2 AND ISLASTBAR,0.005,0.12,0,YB),COLORYELLOW;
DRAWTEXT_FIX(Y3 AND ISLASTBAR,0.005,0.12,0,YC),COLORYELLOW;
DRAWTEXT_FIX(Y4 AND ISLASTBAR,0.005,0.12,0,YD),COLORYELLOW;
DRAWTEXT_FIX(Y5 AND ISLASTBAR,0.005,0.12,0,YE),COLORYELLOW;
DRAWTEXT_FIX(Y6 AND ISLASTBAR,0.005,0.12,0,YF),COLORYELLOW;
DRAWTEXT_FIX(Y7 AND ISLASTBAR,0.005,0.12,0,YG),COLORYELLOW;
DRAWTEXT_FIX(Y8 AND ISLASTBAR,0.005,0.12,0,YH),COLORYELLOW;
DRAWTEXT_FIX(ISLASTBAR,0.005,0.008,0,AA),COLORYELLOW;